1 REM PARRES.BAS
10 CLS
11 KEY OFF
20 PRINT "PARRES 1.1"
30 PRINT "(C) Copyright Kalmeijer Software 1990"
40 REM Bepaling van de te gebruiken weerstanden om bij parallel
50 REM schakeling een gewenste weerstandswaarde te verkrijgen.
60 REM E-12 reeks
70 DATA .82,1,1.2,1.5,1.8,2.2,2.7,3.3,3.9,4.7,5.6,6.8,8.2,10,12,15,18,22
80 CLEAR
81 C = 100
90 PRINT
100 INPUT "Wat is de gewenste weerstandswaarde (in Ohm)"; R
110 PRINT
120 IF R <= 0 THEN END
130 REM wegwerken machten van tien
140 RX = R
150 Y = 0
151 X = O
152 REM Zet machten van tien op nul
160 IF RX < .5 THEN RX = RX * 10: Y = Y + 1: GOTO 160
170 IF RX > 8.2 THEN RX = RX / 10: X = X + 1: GOTO 170
180 RESTORE
190 REM Bepaling van de eerstvolgende E12-waarde die groter is dan de gevraagde
200 REM weerstand
210 READ R1
211 IF R1 < RX THEN GOTO 210
220 RY = R1
230 IF R1 = RX THEN GOTO 1060
240 REM Bepaling van Ra die parallel aan r1 komt te staan
250 RA = R1 * RX / (R1 - RX)
260 REM zoeken van de E12-weerstand R2 die ongeveer gelijk is aan Ra
270 I = 0
280 RESTORE
290 FOR J = 0 TO 11
300 READ R2
310 IF R2 * 10 ^ I >= RA THEN J = 11: GOTO 340
320 RZ = R2
321 K = I
330 NEXT J
340 IF R2 * 10 ^ I >= RA THEN 370
350 I = I + 1
360 GOTO 280
370 REM Herstellen van de machten van 10
380 R1 = R1 * 10 ^ (X - Y)
390 R2 = R2 * 10 ^ (X - Y + I)
400 RZ = RZ * 10 ^ (X - Y + K)
410 REM Berekening van de procentuele afwijking
420 F = ABS((R1 * R2 / (R1 + R2) - R) / R * 10000 \ 1) / 100
430 G = ABS((R1 * RZ / (R1 + RZ) - R) / R * 10000 \ 1) / 100
440 REM Bereken van een betere combinatie
450 IF F < C THEN A = R1: B = R2: C = F
460 IF G < C THEN A = R1: B = RZ: C = G
470 IF R1 >= 2 * R THEN 1000
480 RY = RY + .1
481 R1 = 0
490 RESTORE
500 READ R1: IF R1 < RY THEN 500
510 GOTO 250
1000 REM printen van resultaat
1010 PRINT "Parallel schakeling van R1"; A; "Ohm en R2"; B; "Ohm geeft ";
1020 PRINT "een weerstand van ongeveer"; R; "Ohm met een ";
1030 PRINT USING "theoretische afwijking van #.## %"; C
1040 A = 0
1041 B = 0
1042 C = 100
1050 GOTO 80
1060 PRINT "Om een weerstandswaarde van ongeveer"; R; "Ohm te krijgen, moet ";
1070 PRINT "men een weerstand van"; R; "Ohm nemen."
1080 GOTO 80
